dnl Process this file with autoconf to produce a configure script.
AC_INIT(acgeneral.m4)

AC_ARG_PROGRAM

dnl We use a path for GNU m4 so even if users have another m4 first in
dnl their path, the installer can configure with a path that has GNU m4
dnl first and get that path embedded in the installed autoconf and
dnl autoheader scripts.
AC_PATH_PROGS(M4, gm4 gnum4 m4, m4)
AC_PROG_AWK

dnl We use a path for perl so the #! line in autoscan will work.
AC_PATH_PROG(PERL, perl, no)
AC_SUBST(PERL)dnl
AC_SUBST(SCRIPTS)dnl
if test "$PERL" != no; then
  SCRIPTS=autoscan
else
  AC_MSG_WARN(autoscan will not be built since perl is not found)
fi

AC_PROG_INSTALL

# Work with the GNU or Cygnus source tree layout.
if test -f $srcdir/standards.texi; then
  standards_info=standards.info standards_dvi=standards.dvi
fi
AC_SUBST(standards_info)dnl
AC_SUBST(standards_dvi)dnl

AC_OUTPUT(Makefile testsuite/Makefile)
