* 1.731 Class 03_10, March 11, 2003
* Using parameteric analyusis to derive Pareto tradeoff curve

$offlisting
$offsymxref
$offsymlist
option
        limrow=0
        limcol=0                ;

sets
        i               index for parameter analysis  / 1*166 /  ;

scalar
        F1   ;
variables
        envq    environmental quality   ;
positive variables
        x1      crop 1 production
        x2      crop 2 production
        F2      revenue              ;

equations
        minrevenue             'minimum crop revenue'
        water                  'water contraint'
        land                   'land constraint'
        mincrop                'minimum crop production'
        quality                'environmental quality'        ;

        minrevenue..     6*x1+11*x2 =G= F1     ;
        water..       2*x1+x2 =L= 104     ;
        land..        x1+2*x2 =L= 76  ;
        mincrop..     x1+x2 =g=25    ;
        quality..     envq =e= -5*x1-2*x2   ;
model tradeoff /all/                                           ;

file results  /pareto.res/                                     ;
put results                                                     ;
results.nd = 4          ;
loop(i,
        F1 = 275+(ord(i)-1)*1    ;
        solve tradeoff using lp maximizing envq                ;
        put @5, F1, @15, envq.l, minrevenue.m, x1.l, x2.l    /          ;
    )                                                           ;
putclose results                                                ;