**********************************************************
*            (©) National Semiconductor, Inc.            *
*        Models developed and under copyright by:        *
*              National Semiconductor, Inc.              *
*                                                        *
*   Reproduced with permission of National Semiconductor *
*   Corporation.                                         *
*                                                        *
*   The models and subcircuits in this file are provided *
*   as is, without any warranties of any kind. National  *
*   Semiconductor does not assume any responsibility for *
*   the use of this file, and specifically disclaims all *
*   warranties, including the implied warranties of      *
*   merchantability or fitness for any particular        *
*   purpose.                                             *
*                                                        *
**********************************************************
*
*LM741 OPERATIONAL AMPLIFIER MACRO-MODEL
*
* connections:      non-inverting input
*                   |   inverting input
*                   |   |   positive power supply
*                   |   |   |   negative power supply
*                   |   |   |   |   output
*                   |   |   |   |   |
*                   |   |   |   |   |
.SUBCKT LM741       1   2  99  50  28
*
*Features:
*Improved performance over industry standards
*Plug-in replacement for LM709,LM201,MC1439,748
*Input and output overload protection
*
IOS 2 1 20N
R1 1 3 250K
R2 3 2 250K
I1 4 50 100U
R3 5 99 517
R4 6 99 517
Q1 5 2 4 QX741
Q2 6 7 4 QX741
C4 5 6 60.3614P
I2 99 50 1.6MA
*EOS 7 1 POLY(1) 16 49 1E-3 1
BOS 7 1 v= 1E-3 + 1*v(16,49) 
R8 99 49 40K
R9 49 50 40K
V2 99 8 1.63
D1 9 8 DX741
D2 10 9 DX741
V3 10 50 1.63
EH 99 98 99 49 1
G1 98 9 5 6 2.1E-3
R5 98 9 95.493MEG
C3 98 9 333.33P
G3 98 15 9 49 1E-6
R12 98 15 1MEG
C5 98 15 5.3052E-15
G4 98 16 3 49 3.1623E-8
L2 98 17 530.5M
R13 17 16 1K
*F6 50 99 POLY(1) V6 450U 1
B6 50 99 i= 450E-6 + 1*i(V6)
E1 99 23 99 15 1
R16 24 23 25
D5 26 24 DX741
V6 26 22 0.65V
R17 23 25 25
D6 25 27 DX741
V7 22 27 0.65V
V5 22 21 0.18V
D4 21 15 DX741
V4 20 22 0.18V
D3 15 20 DX741
L3 22 28 100P
RL3 22 28 100K
.ENDS LM741
.MODEL DX741 D(IS=1E-15)
.MODEL QX741 NPN(BF=625)
*