#include <avr/pgmspace.h>

#define PACKS 64 // number of packets to send


unsigned int location = 0;

byte value0 = 0;
byte value1 = 0;
byte value2 = 0;
byte x = 0;
byte color = 1;
byte packet = 0;
byte flag = 0;
byte red = 0;
byte blue = 0;
byte green = 0;
byte redtemp = 0;
byte bluetemp = 0;
byte greentemp = 0;

void setup() {
  // setup io
  PORTD |= (1<<PORTD1); // set pd1 to high
  DDRD |= (1<<DDD1); // set pd1 to output
  // setup ADC
  ADMUX = 0x60; // start with ADC0 - internal VCC for Vref, left adjust
  ADCSRA = 0xdf; // ADC enable, ck/128 = 125kHz
  ADCSRB = 0x00; // free running mode
  DIDR0 = 0x3f; // turn off digital inputs for ADC channels
  // setup USART for DMX transfers
  UCSR0A = 0;
  UCSR0B = (0<<UDRIE0)|(1<<TXCIE0)|(1<<TXEN0);
  UCSR0C = (1<<USBS0)|(1<<UCSZ01)|(1<<UCSZ00);
  UBRR0H = 0; // set data rate to 250kbps
  UBRR0L = 3;
  TIMSK0 = 0; // shut off timer0 interrupts
  // start USART0 running
  UDR0 = 0;
}

void loop() {
  while (flag == 1) {
    redtemp = value0;
    bluetemp = value1;
    greentemp = value2;
    flag = 0; // reset start flag 
  }
}

ISR(ADC_vect) {
  byte temp1 = ADCH; // add to temp register
  ++x;
  if (x == 1) value0 = temp1;
  else if (x == 2) value1 = temp1;
  else { 
    value2 = temp1;
    x = 0;
  }
  ADMUX = 0x60 | x;
  ADCSRA = 0xdf;
}

ISR(USART_TX_vect) {
  if (packet == 0) {
    // send out packet start sequence
    UCSR0B &= ~(1<<TXEN0); // turn off usart0 to release tx line
    PORTD &= ~(1<<PORTD1); // set portd1 to low for frame start
    unsigned int temp3 = 320; // hold low for 100us
    while (temp3 > 0) {
      asm volatile("nop");
      --temp3;
    } 
    PORTD |= (1<<PORTD1); // set portd1 to high for frame start
    temp3 = 57; // hold high for 18us
    while (temp3 > 0) {
      asm volatile("nop");
      --temp3;
    } 
    UCSR0B |= (1<<TXEN0); // reenable usart0
    UDR0 = 0; // send a blank data frame
    // update color registers
    green = greentemp;
    red = redtemp;
    blue = bluetemp;
    packet = PACKS; // set total rgb packets to send
    flag = 1; // set flag to indicate data is going to be sent out
  }
  else {
    --color;
    if (color == 0) {
      UDR0 = green;
      color = 3;
    }
    else if (color == 1) {
      UDR0 = red;
    }
    else {
      UDR0 = blue;
      --packet;
    }
  }
}