#include <avr/pgmspace.h>

#define PACKS 48 // number of packets to send

byte green[PACKS] = {0};
byte blue[PACKS] = {0};
byte red[PACKS] = {0};

byte color = 0;
byte packet = 0;
volatile byte flag = 0;
byte dir = 0;
byte test = 0;

void setup() {
  // setup io
  PORTD |= (1<<PORTD1); // set pd1 to high
  DDRD |= (1<<DDD1); // set pd1 to output
  // setup USART for DMX transfers
  UCSR0A = 0;
  UCSR0B = (0<<UDRIE0)|(1<<TXCIE0)|(1<<TXEN0);
  UCSR0C = (1<<USBS0)|(1<<UCSZ01)|(1<<UCSZ00);
  UBRR0H = 0; // set data rate to 250kbps
  UBRR0L = 3;
//  TIMSK0 = 0; // shut off timer0 interrupts - uncomment this if you dont need delay()
}

void loop() {
  while (flag == 1); // wait for packets to be sent
  delay(100); // for slower patterns to set timing
  // put packet generation code here
  if (dir == 0) {
    test++;
    if (test == 7) dir = 1;
  }
  else {
    test--;
    if (test == 0) dir = 0;
  }
  for (byte i = 0; i < PACKS; i++) {
    green[i] = 0;
    red[i] = 0;
    blue[i] = 0;
  }
  red[test] = 255;
  if (test > 1) red[test-1] = 64;
  if (test > 2) red[test-2] = 24;
  if (test < 6) red[test+1] = 64;
  if (test < 5) red[test+2] = 24;
  // send out packet start sequence
  UCSR0B &= ~(1<<TXEN0); // turn off usart0 to release tx line
  PORTD &= ~(1<<PORTD1); // set portd1 to low for frame start
  unsigned int temp3 = 320; // hold low for 100us
  while (temp3 > 0) {
    asm volatile("nop");
    --temp3;
  }
  PORTD |= (1<<PORTD1); // set portd1 to high for frame start
  temp3 = 57; // hold high for 18us
  while (temp3 > 0) {
    asm volatile("nop");
    --temp3;
  } 
  UCSR0B |= (1<<TXEN0); // reenable usart0
  UDR0 = 0; // send a blank data frame
  packet = 0; // set total rgb packets to send
  flag = 1; // set flag to indicate data is going to be sent out 
  color = 0;
}

ISR(USART_TX_vect) {
  if (packet == PACKS) flag = 0; // let main know all packets sent
  else {
    if (color == 0) {
      UDR0 = red[packet];
      color = 1;
    }
    else if (color == 1) {
      UDR0 = green[packet];
      color = 2;
    }
    else {
      UDR0 = blue[packet];
      color = 0;
      ++packet;
    }
  }
}