// DMX transmitter for atmega328p
// it consumes the USART, so serial transfers cant be used

#define SIZE 32 // frame size if you want to do it this way
byte dmx_buffer[SIZE]; // allocate buffer space
volatile byte dmx_ptr = 0;
volatile byte dmx_state = 0; // state tracker
void dmx_send(void); // dmx transfer prototype

void setup() {
  // initialize uart for data transfer
  UBRR0H = ((F_CPU/250000/16) - 1) >> 8;
  UBRR0L = ((F_CPU/250000/16) - 1);
  UCSR0A = 1<<UDRE0;
  UCSR0C = 1<<USBS0 | 1<<UCSZ01 | 1<<UCSZ00; // 2 stop bits,8 data bitss
  UCSR0B = 1<<TXEN0; // turn it on
}

void loop() {
  while(dmx_state); // check if last buffer was sent out
  // fill buffer with some new data
  for (byte i = 0; i < SIZE; i++) {
    dmx_buffer[i] = i << 3;
  }
  // send out dmx data
  dmx_send();
}

ISR(USART0_TXC_vect) {
  // handle data transfers
  // check for state 3 first as its most probable
  if (dmx_state == 3) {
    UDR0 = dmx_buffer[dmx_ptr];
    dmx_ptr++;
    if (dmx_ptr >= SIZE) {
      dmx_state = 4; // last byte sent
    }
  }
  else if (dmx_state == 1) {
    // reset baudrate generator
    UBRR0H = ((F_CPU/250000/16) - 1) >> 8;
    UBRR0L = ((F_CPU/250000/16) - 1);
    UDR0 = 0; // send slot0 blank space
    dmx_state = 2; // set to slot0 transmit mode
  }
  else if (dmx_state == 2) {
    UDR0 = dmx_buffer[0]; // send first data byte
    dmx_ptr = 1; // set pointer to next data byte
    dmx_state = 3; // set to data transfer mode
  }
  else {
    UCSR0B &= ~(1<<TXCIE0); // disable tx complete interrupt
    UCSR0A |= 1<<TXC0; // clear flag if set
    dmx_state = 0; // reset - bad condition or done
  }
}

void dmx_send() {
  dmx_state = 1; // set to BREAK transfer
  // set usart for really slow transfer for BREAK signal
  // this will produce a BREAK of 112.5us
  // and a MAB of 25us
  UBRR0H = ((F_CPU/80000/16) - 1) >> 8;
  UBRR0L = ((F_CPU/80000/16) - 1);
  UCSR0B |= 1<<TXCIE0; // enable tx complete interrupt
  UDR0 = 0;
}