2-stage CS voltage amplifier

.options post
.op

.model N1 NMOS Level=1 VTO=0.7 TOX=1.7E-08 UO=250 LAMBDA=6.67E-02
+ GAMMA=0.6 CGSO=5E-10 CGDO=5E-10 CJ=1.0E-04 CJSW=5.0E-10 PB=0.95

.model N2 NMOS Level=1 VTO=0.7 TOX=1.7E-08 UO=250 LAMBDA=6.67E-02
+ GAMMA=0.6 CGSO=5E-10 CGDO=5E-10 CJ=1.0E-04 CJSW=5.0E-10 PB=0.95

.model P1 PMOS LEVEL=1 VTO=-0.7 TOX=1.7E-08 UO=125 LAMBDA=1.712E-02
+ GAMMA=0.6 CGSO=5E-10 CGDO=5E-10 CJ=3.0E-04 CJSW=3.5E-10 PB=0.9

.model P2 PMOS LEVEL=1 VTO=-0.7 TOX=1.7E-08 UO=125 LAMBDA=6.67E-02
+ GAMMA=0.6 CGSO=5E-10 CGDO=5E-10 CJ=3.0E-04 CJSW=3.5E-10 PB=0.9

** sources and inputs **

Vin    1  0 ac=1,0 dc=0.8
Vdd    5  0 dc 5
Va     4  0 dc 3.58573
Vb     6  0 dc 4
Rs     1  2    1k

** mosfets **

.param    l_diff=6u
.param    w_all=6u
.param    p_1='w_all+2*l_diff'     a_1='w_all*l_diff'
Mp1 3 4 5 5 P1 w=6u l=5.84u pd=p_1 ps=p_1 ad=a_1 as=a_1

Mn1 3 2 0 0 N1 w=39.3u l=1.5u pd=51.3u ps=51.3u ad=235.8p as=235.8p

Mp2 7 6 5 5 P2 w=14.8u l=1.5u pd=26.8u ps=26.8u ad=88.8p as=88.8p

Mn2 7 3 0 0 N2 w=6u l=1.5u pd=p_1 ps=p_1 ad=a_1 as=a_1

** load and stuff **

C1 7 0 1p

.dc vin 0 5 0.001

.ac dec 40 1 1g
.print   ac mag=par('20*log10(v(7))')
.MEASURE AC VMAX MAX V(7)
.MEASURE AC F3DB WHEN V(7)='VMAX*.707' FALL=1
.measure ac funity when V(7)=1 fall=1


.end