" PRX_CONV_ - Conversion for printronix remote printer.
"	coded by R. J. Sonnier


" This module performs the necessary conversion for printing on the
" printronix remote printer.
"
" The manner in which this procedure is utilized is described in detail
" in the listing of prt_conv_.
"
" A media code character will be inserted at the beginning of each
" output line.  This character must have been placed in pci.temp
" before this procedure is called.


	name	printronix_conv_

	segdef	teleprinter
	segdef	printer


	temp	char		place for slew and record separator characters


teleprinter:
printer:
	tra	sb|0
	tra	prx_send_chars
	tra	prx_send_slew_pattern
	tra	prx_send_slew_count

" 

	include	prt_conv_info


" 

prx_send_chars:

spaceloop:
	eaq	0,2		white space count in QU
	tmoz	nospace		skip if no white space

blankout:	mlr	(),(pr,rl),fill(040)  insert requisite number of blanks
	desc9a	*,0		..
	desc9a	bb|0,qu		..

	a9bd	bb|0,qu		bump output pointer

nospace:	mlr	(pr,rl),(pr,rl)	copy characters into output
	desc9a	bp|0,au		..
	desc9a	bb|0,au		..

	a9bd	bp|0,au		step input and output pointers
	a9bd	bb|0,au		..

	eax2	0		clear white space counter
	tra	sb|0		return to caller


" 

prx_send_slew_pattern:
	lda	ff_char		insert FF character
	sta	char		save characters

send_slew:
	mlr	(pr),(pr),fill(0)	pad last word with zeroes
	desc9a	char,2		..
	desc9a	bb|0,2+3		..

	ldq	2,dl		increment output pointer
	a9bd	bb|0,ql		..

	tra	sb|0		return to caller



prx_send_slew_count:
	cmpa	0,dl		is line_count zero?
	tnz	*+6		if zero ...
	mlr	(),(pr),fill(015) send a carriage return
	desc9a	*,0
	desc9a	bb|0,1
	lda	1,dl		bump ptr 1 character
	tra	*+4

	mlr	(),(pr,rl),fill(012) insert new_lines
	desc9a	*,0
	desc9a	bb|0,al

	a9bd	bb|0,al

	lda	0,dl		zero reg a
	tra	sb|0		go back

" 

vt_char:	vfd	o9/012
ff_char:	vfd	o9/014
hs_char:	vfd	o9/037
cr_char:  vfd       o9/015




	end
"
"
"                                          -----------------------------------------------------------
"
"
"
" Historical Background
"
" This edition of the Multics software materials and documentation is provided and donated
" to Massachusetts Institute of Technology by Group Bull including Bull HN Information Systems Inc. 
" as a contribution to computer science knowledge.  
" This donation is made also to give evidence of the common contributions of Massachusetts Institute of Technology,
" Bell Laboratories, General Electric, Honeywell Information Systems Inc., Honeywell Bull Inc., Groupe Bull
" and Bull HN Information Systems Inc. to the development of this operating system. 
" Multics development was initiated by Massachusetts Institute of Technology Project MAC (1963-1970),
" renamed the MIT Laboratory for Computer Science and Artificial Intelligence in the mid 1970s, under the leadership
" of Professor Fernando Jose Corbato. Users consider that Multics provided the best software architecture for
" managing computer hardware properly and for executing programs. Many subsequent operating systems
" incorporated Multics principles.
" Multics was distributed in 1975 to 2000 by Group Bull in Europe , and in the U.S. by Bull HN Information Systems Inc., 
" as successor in interest by change in name only to Honeywell Bull Inc. and Honeywell Information Systems Inc. .
"
"                                          -----------------------------------------------------------
"
" Permission to use, copy, modify, and distribute these programs and their documentation for any purpose and without
" fee is hereby granted,provided that the below copyright notice and historical background appear in all copies
" and that both the copyright notice and historical background and this permission notice appear in supporting
" documentation, and that the names of MIT, HIS, Bull or Bull HN not be used in advertising or publicity pertaining
" to distribution of the programs without specific prior written permission.
"    Copyright 1972 by Massachusetts Institute of Technology and Honeywell Information Systems Inc.
"    Copyright 2006 by Bull HN Information Systems Inc.
"    Copyright 2006 by Bull SAS
"    All Rights Reserved
"
"